home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / pctj8504.arc / SRPNSKI.BAS < prev    next >
BASIC Source File  |  1986-09-14  |  2KB  |  54 lines
  1. 10 SCREEN 1,1:KEY OFF:CLS
  2. 20 LOCATE 12,15:PRINT "WAIT...";
  3. 30 '
  4. 40 DIM UU$(10),UR$(10),UL$(10)
  5. 50 DIM DD$(10),DR$(10),DL$(10)
  6. 60 DIM RR$(10),RD$(10),RU$(10)
  7. 70 DIM LL$(10),LD$(10),LU$(10)
  8. 80 '
  9. 90 UR$(0)="E2":UL$(0)="U2":UU$(0)="U2"
  10. 100 DL$(0)="G2":DR$(0)="D2":DD$(0)="D2"
  11. 110 RD$(0)="F2":RU$(0)="R2":RR$(0)="R2"
  12. 120 LU$(0)="H2":LD$(0)="L2":LL$(0)="L2"
  13. 130 '
  14. 140 FOR K=1 TO 10
  15. 150 MUU$="XUU$("+STR$(K-1)+");"
  16. 160 MUL$="XUL$("+STR$(K-1)+");"
  17. 170 MUR$="XUR$("+STR$(K-1)+");"
  18. 180 MDD$="XDD$("+STR$(K-1)+");"
  19. 190 MDR$="XDR$("+STR$(K-1)+");"
  20. 200 MDL$="XDL$("+STR$(K-1)+");"
  21. 210 MRR$="XRR$("+STR$(K-1)+");"
  22. 220 MRU$="XRU$("+STR$(K-1)+");"
  23. 230 MRD$="XRD$("+STR$(K-1)+");"
  24. 240 MLL$="XLL$("+STR$(K-1)+");"
  25. 250 MLD$="XLD$("+STR$(K-1)+");"
  26. 260 MLU$="XLU$("+STR$(K-1)+");"
  27. 270 '
  28. 280 UU$(K)=MRU$+MUR$+MUU$
  29. 290 UL$(K)=MUL$+MLU$+MLL$
  30. 300 UR$(K)=MUL$+MLU$+MUR$+MRD$+MRR$
  31. 310 DD$(K)=MLD$+MDL$+MDD$
  32. 320 DR$(K)=MDR$+MRD$+MRR$
  33. 330 DL$(K)=MDR$+MRD$+MDL$+MLU$+MLL$
  34. 340 RR$(K)=MDR$+MRD$+MRR$
  35. 350 RU$(K)=MRU$+MUR$+MUU$
  36. 360 RD$(K)=MRU$+MUR$+MRD$+MDL$+MDD$
  37. 370 LL$(K)=MUL$+MLU$+MLL$
  38. 380 LD$(K)=MLD$+MDL$+MDD$
  39. 390 LU$(K)=MLD$+MDL$+MLU$+MUR$+MUU$
  40. 400 NEXT K
  41. 410 '
  42. 420 FOR K=1 TO 4:SIDE=2^(K+1)
  43. 430 SCAL=128/SIDE:CLS 
  44. 440 LOCATE 1,1:PRINT "Level";K;
  45. 450 '
  46. 460 DRAW "C3BM160,90;S=SCAL;BL4"
  47. 470 DRAW UR$(K)+RD$(K)+DL$(K)+LU$(K)
  48. 480 DRAW "BR P3,3"
  49. 490 '
  50. 500 LOCATE 22,1    
  51. 510 INPUT "Press ENTER to continue";A$
  52. 520 NEXT K
  53. 530 END
  54.